configure: check for readline properly

configure.ac

@@ -1,8 +1,9 @@
 AC_INIT(configure.ac)
-
 AC_CONFIG_HEADERS(config.h)
 AM_INIT_AUTOMAKE(ncmpcpp, 0.7_beta2dev)
 
+m4_include([m4/ax_lib_readline.m4])
+
 AC_PREREQ(2.59)
 
 AC_LANG_CPLUSPLUS
@@ -223,13 +224,13 @@ PKG_CHECK_MODULES([libmpdclient], [libmpdclient >= 2.8], [
 dnl =========================
 dnl = checking for readline =
 dnl =========================
-AC_CHECK_HEADERS([readline/readline.h readline/history.h],
+AX_LIB_READLINE
-	AC_CHECK_LIB(readline, rl_initialize, LIBS="$LIBS -lreadline",
+if test "$ax_cv_lib_readline" = "no"; then
-		AC_MSG_ERROR([readline headers found but there is no readline library to make use of])
+  AC_MSG_ERROR([no readline compatible library found])
-	),
+fi
-	AC_MSG_ERROR([no readline/readline.h header file found])
+if test "$ax_cv_lib_readline_history" = "no"; then
-)
+  AC_MSG_WARN([readline library has no history functionality])
-
+fi
 
 dnl ========================
 dnl = checking for pthread =

m4/ax_lib_readline.m4

@@ -0,0 +1,107 @@
+# ===========================================================================
+#      http://www.gnu.org/software/autoconf-archive/ax_lib_readline.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_LIB_READLINE
+#
+# DESCRIPTION
+#
+#   Searches for a readline compatible library. If found, defines
+#   `HAVE_LIBREADLINE'. If the found library has the `add_history' function,
+#   sets also `HAVE_READLINE_HISTORY'. Also checks for the locations of the
+#   necessary include files and sets `HAVE_READLINE_H' or
+#   `HAVE_READLINE_READLINE_H' and `HAVE_READLINE_HISTORY_H' or
+#   'HAVE_HISTORY_H' if the corresponding include files exists.
+#
+#   The libraries that may be readline compatible are `libedit',
+#   `libeditline' and `libreadline'. Sometimes we need to link a termcap
+#   library for readline to work, this macro tests these cases too by trying
+#   to link with `libtermcap', `libcurses' or `libncurses' before giving up.
+#
+#   Here is an example of how to use the information provided by this macro
+#   to perform the necessary includes or declarations in a C file:
+#
+#     #ifdef HAVE_LIBREADLINE
+#     #  if defined(HAVE_READLINE_READLINE_H)
+#     #    include <readline/readline.h>
+#     #  elif defined(HAVE_READLINE_H)
+#     #    include <readline.h>
+#     #  else /* !defined(HAVE_READLINE_H) */
+#     extern char *readline ();
+#     #  endif /* !defined(HAVE_READLINE_H) */
+#     char *cmdline = NULL;
+#     #else /* !defined(HAVE_READLINE_READLINE_H) */
+#       /* no readline */
+#     #endif /* HAVE_LIBREADLINE */
+#
+#     #ifdef HAVE_READLINE_HISTORY
+#     #  if defined(HAVE_READLINE_HISTORY_H)
+#     #    include <readline/history.h>
+#     #  elif defined(HAVE_HISTORY_H)
+#     #    include <history.h>
+#     #  else /* !defined(HAVE_HISTORY_H) */
+#     extern void add_history ();
+#     extern int write_history ();
+#     extern int read_history ();
+#     #  endif /* defined(HAVE_READLINE_HISTORY_H) */
+#       /* no history */
+#     #endif /* HAVE_READLINE_HISTORY */
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Ville Laurikari <vl@iki.fi>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 6
+
+AU_ALIAS([VL_LIB_READLINE], [AX_LIB_READLINE])
+AC_DEFUN([AX_LIB_READLINE], [
+  AC_CACHE_CHECK([for a readline compatible library],
+                 ax_cv_lib_readline, [
+    ORIG_LIBS="$LIBS"
+    for readline_lib in readline edit editline; do
+      for termcap_lib in "" termcap curses ncurses; do
+        if test -z "$termcap_lib"; then
+          TRY_LIB="-l$readline_lib"
+        else
+          TRY_LIB="-l$readline_lib -l$termcap_lib"
+        fi
+        LIBS="$ORIG_LIBS $TRY_LIB"
+        AC_TRY_LINK_FUNC(readline, ax_cv_lib_readline="$TRY_LIB")
+        if test -n "$ax_cv_lib_readline"; then
+          break
+        fi
+      done
+      if test -n "$ax_cv_lib_readline"; then
+        break
+      fi
+    done
+    if test -z "$ax_cv_lib_readline"; then
+      ax_cv_lib_readline="no"
+    fi
+    LIBS="$ORIG_LIBS"
+  ])
+
+  if test "$ax_cv_lib_readline" != "no"; then
+    LIBS="$LIBS $ax_cv_lib_readline"
+    AC_DEFINE(HAVE_LIBREADLINE, 1,
+              [Define if you have a readline compatible library])
+    AC_CHECK_HEADERS(readline.h readline/readline.h)
+    AC_CACHE_CHECK([whether readline supports history],
+                   ax_cv_lib_readline_history, [
+      ax_cv_lib_readline_history="no"
+      AC_TRY_LINK_FUNC(add_history, ax_cv_lib_readline_history="yes")
+    ])
+    if test "$ax_cv_lib_readline_history" = "yes"; then
+      AC_DEFINE(HAVE_READLINE_HISTORY, 1,
+                [Define if your readline library has \`add_history'])
+      AC_CHECK_HEADERS(history.h readline/history.h)
+    fi
+  fi
+])dnl

src/Makefile.am

@@ -63,6 +63,7 @@ noinst_HEADERS = \
 	utility/functional.h \
 	utility/html.h \
 	utility/option_parser.h \
+	utility/readline.h \
 	utility/string.h \
 	utility/type_conversions.h \
 	utility/wide_string.h \

src/actions.cpp

@@ -28,7 +28,6 @@
 #include <boost/lexical_cast.hpp>
 #include <algorithm>
 #include <iostream>
-#include <readline/readline.h>
 
 #include "actions.h"
 #include "charset.h"
@@ -57,6 +56,7 @@
 #include "server_info.h"
 #include "song_info.h"
 #include "outputs.h"
+#include "utility/readline.h"
 #include "utility/string.h"
 #include "utility/type_conversions.h"
 #include "tag_editor.h"

src/utility/readline.h

@@ -0,0 +1,38 @@
+/***************************************************************************
+ *   Copyright (C) 2008-2014 by Andrzej Rybczak                            *
+ *   electricityispower@gmail.com                                          *
+ *                                                                         *
+ *   This program is free software; you can redistribute it and/or modify  *
+ *   it under the terms of the GNU General Public License as published by  *
+ *   the Free Software Foundation; either version 2 of the License, or     *
+ *   (at your option) any later version.                                   *
+ *                                                                         *
+ *   This program is distributed in the hope that it will be useful,       *
+ *   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
+ *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
+ *   GNU General Public License for more details.                          *
+ *                                                                         *
+ *   You should have received a copy of the GNU General Public License     *
+ *   along with this program; if not, write to the                         *
+ *   Free Software Foundation, Inc.,                                       *
+ *   51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA.              *
+ ***************************************************************************/
+
+#ifndef NCMPCPP_UTILITY_READLINE_H
+#define NCMPCPP_UTILITY_READLINE_H
+
+#include "config.h"
+
+#if defined(HAVE_READLINE_HISTORY_H)
+# include <readline/history.h>
+#endif // HAVE_READLINE_HISTORY
+
+#if defined(HAVE_READLINE_H)
+# include <readline.h>
+#elif defined(HAVE_READLINE_READLINE_H)
+# include <readline/readline.h>
+#else
+# error "readline is not available"
+#endif
+
+#endif // NCMPCPP_READLINE_UTILITY_H

src/window.cpp

@@ -23,12 +23,10 @@
 #include <cstdio>
 #include <cstdlib>
 #include <iostream>
-#include <readline/history.h>
-#include <readline/readline.h>
-
 #include <sys/select.h>
 #include <unistd.h>
 
+#include "utility/readline.h"
 #include "utility/string.h"
 #include "utility/wide_string.h"
 #include "window.h"
@@ -1111,8 +1109,10 @@ std::string Window::prompt(const std::string &base, size_t width, bool encrypted
 	curs_set(0);
 	if (input != nullptr)
 	{
+#ifdef HAVE_READLINE_HISTORY_H
 		if (!encrypted && input[0] != 0)
 			add_history(input);
+#endif // HAVE_READLINE_HISTORY_H
 		result = input;
 		free(input);
 	}