Add pygmalion-virtualenv theme (#5139)

themes/pygmalion-virtualenv.zsh-theme

@@ -0,0 +1,50 @@
+# Yay! High voltage and arrows!
+
+
+function _virtualenv_prompt_info {
+    if [[ -n "$(whence virtualenv_prompt_info)" ]]; then
+        if [ -n "$(whence pyenv_prompt_info)" ]; then
+            if [ "$1" = "inline" ]; then
+                ZSH_THEME_VIRTUAL_ENV_PROMPT_PREFIX=%{$fg[blue]%}"::%{$fg[red]%}"
+                ZSH_THEME_VIRTUAL_ENV_PROMPT_SUFFIX=""
+                virtualenv_prompt_info
+            fi
+            [ "$(pyenv_prompt_info)" = "${PYENV_PROMPT_DEFAULT_VERSION}" ] && virtualenv_prompt_info
+        else
+            virtualenv_prompt_info
+        fi
+    fi
+}
+
+prompt_setup_pygmalion(){
+  ZSH_THEME_GIT_PROMPT_PREFIX="%{$reset_color%}%{$fg[green]%}"
+  ZSH_THEME_GIT_PROMPT_SUFFIX="%{$reset_color%} "
+  ZSH_THEME_GIT_PROMPT_DIRTY="%{$fg[yellow]%}⚡%{$reset_color%}"
+  ZSH_THEME_GIT_PROMPT_CLEAN=""
+
+  base_prompt='$(_virtualenv_prompt_info)%{$fg[magenta]%}%n%{$reset_color%}%{$fg[cyan]%}@%{$reset_color%}%{$fg[yellow]%}%m%{$reset_color%}%{$fg[red]%}:%{$reset_color%}%{$fg[cyan]%}%0~%{$reset_color%}%{$fg[red]%}|%{$reset_color%}'
+  post_prompt='%{$fg[cyan]%}⇒%{$reset_color%}  '
+
+  base_prompt_nocolor=$(echo "$base_prompt" | perl -pe "s/%\{[^}]+\}//g")
+  post_prompt_nocolor=$(echo "$post_prompt" | perl -pe "s/%\{[^}]+\}//g")
+
+  precmd_functions+=(prompt_pygmalion_precmd)
+}
+
+prompt_pygmalion_precmd(){
+  local gitinfo=$(git_prompt_info)
+  local gitinfo_nocolor=$(echo "$gitinfo" | perl -pe "s/%\{[^}]+\}//g")
+  local exp_nocolor="$(print -P \"$base_prompt_nocolor$gitinfo_nocolor$post_prompt_nocolor\")"
+  local prompt_length=${#exp_nocolor}
+
+  local nl=""
+
+  if [[ $prompt_length -gt 40 ]]; then
+    nl=$'\n%{\r%}';
+  fi
+  PROMPT="$base_prompt$gitinfo$nl$post_prompt"
+}
+
+prompt_setup_pygmalion
+
+